Quantum Mechanics

Path Integral Quantization

From Classical to Quantum

Historical Review

History: What is the Nature of Light?

The corpuscular (particle) theory: light is composed of steady stream of particles carrying the energy and travelling along rays in the speed of light.

The wave theory: light is wave-like, propagating in the space and time.

The Wave-Particle Wars in History

Concluding Remarks

Light: originally considered as wave, also behaves like particle.

Electrons, α particles (( ^4)He nucleus): originally considered as particles, also behave like wave.

Quantization of Light

Geometric Optics

Geometric optics is the particle mechanics of light (light travels along a path)

Its basic principle is Fermat’s Principle

The optical path length is defined by

L(A→B)=(∫_A^B)nds,

where n is the refractive index of the medium and ds is an infinitesimal displacement along the ray.

The optical path length is simply related to the light travelling time T by L=c T, where c is the speed of light in vacuum. So extremization of either of them will be equivalent.

Eikonal equation (Newton’s law of light)

n(d/(dt))((n^2)((dx)/(dt)))=∇n.

It can be derived from Fermat’s principle.

Refraction (Snell’s law)

Module[{x0=-1,y0=-1,θ=30Degree,n,tend=5,sol,data,xmin,xmax,ymin,ymax,colbg=ColorData["Legacy"]["DodgerBlue"],colray=ColorData["Legacy"]["Firebrick"]},n[x_,y_]:=1.366+0.366Tanh[25y];sol=NDSolve[{n[x[t],y[t]]D[n[x[t],y[t]]^2D[x[t],t],t]==D[n[x[t],y[t]],x[t]],n[x[t],y[t]]D[n[x[t],y[t]]^2D[y[t],t],t]==D[n[x[t],y[t]],y[t]],x[0]==x0,y[0]==y0,x'[0]==Cos[θ]/n[x0,y0],y'[0]==Sin[θ]/n[x0,y0]},{x,y},{t,0,tend}];data=First@Cases[ParametricPlot[Evaluate[{x[t],y[t]}/.sol],{t,0,tend},PlotPoints->10,MaxRecursion->3],Line[pts_]:>pts,∞];{{xmin,xmax},{ymin,ymax}}={Min[#],Max[#]}&/@Thread[data];Show[ContourPlot[n[x,y],{x,xmin,xmax},{y,ymin,ymax},Contours->16,ContourStyle->None,ColorFunction->(Blend[{White,colbg},Rescale[#,{0.9,2.0}]]&),ColorFunctionScaling->False],Graphics[{AbsoluteThickness[1.2],colray,Arrowheads[{{0.001,0.2,Arrowhead[]},{0.001,0.8,Arrowhead[]}}],Arrow[data]}],AspectRatio->Automatic,PlotRangePadding->0.05,FrameTicks->None,ImageSize->120]]

Total reflection

Module[{x0=-1,y0=1,θ=-45Degree,n,tend=6.6,sol,data,xmin,xmax,ymin,ymax,colbg=ColorData["Legacy"]["DodgerBlue"],colray=ColorData["Legacy"]["Firebrick"]},n[x_,y_]:=1.3+0.3Tanh[3y];sol=NDSolve[{n[x[t],y[t]]D[n[x[t],y[t]]^2D[x[t],t],t]==D[n[x[t],y[t]],x[t]],n[x[t],y[t]]D[n[x[t],y[t]]^2D[y[t],t],t]==D[n[x[t],y[t]],y[t]],x[0]==x0,y[0]==y0,x'[0]==Cos[θ]/n[x0,y0],y'[0]==Sin[θ]/n[x0,y0]},{x,y},{t,0,tend}];data=First@Cases[ParametricPlot[Evaluate[{x[t],y[t]}/.sol],{t,0,tend},PlotPoints->10,MaxRecursion->3],Line[pts_]:>pts,∞];{{xmin,xmax},{ymin,ymax}}={Min[#],Max[#]}&/@Thread[data];Show[ContourPlot[n[x,y],{x,xmin,xmax},{y,ymin-0.5,ymax},Contours->16,ContourStyle->None,ColorFunction->(Blend[{White,colbg},Rescale[#,{0.9,2.0}]]&),ColorFunctionScaling->False],Graphics[{AbsoluteThickness[1.2],colray,Arrowheads[{{0.001,0.2,Arrowhead[]},{0.001,0.8,Arrowhead[]}}],Arrow[data]}],AspectRatio->Automatic,PlotRangePadding->0.05,FrameTicks->None,ImageSize->140]]

Gradient-index (GRIN) optics

Module[{x0=-5,θ=0Degree,n,tend=13,sols,datas,colbg=ColorData["Legacy"]["DodgerBlue"],colray=ColorData["Legacy"]["Firebrick"]},n[x_,y_]:=1+0.8Exp[-((x/2)^10+y^2/14)];sols=NDSolve[{n[x[t],y[t]]D[n[x[t],y[t]]^2D[x[t],t],t]==D[n[x[t],y[t]],x[t]],n[x[t],y[t]]D[n[x[t],y[t]]^2D[y[t],t],t]==D[n[x[t],y[t]],y[t]],x[0]==x0,y[0]==#,x'[0]==Cos[θ]/n[x0,#],y'[0]==Sin[θ]/n[x0,#]},{x,y},{t,0,tend}]&/@{-2,-1,0,1,2};datas=Cases[ParametricPlot[Evaluate[{x[t],y[t]}/.sols],{t,0,tend},PlotPoints->10,MaxRecursion->3],Line[pts_]:>pts,∞];
Show[ContourPlot[n[x,y],{x,-5,5},{y,-5,5},Contours->16,ContourStyle->None,PlotRange->All,ColorFunction->(Blend[{White,colbg},Rescale[#,{0.9,2.0}]]&),ColorFunctionScaling->False],Graphics[{AbsoluteThickness[1.2],colray,Arrowheads[{{0.001,0.2,Arrowhead[]},{0.001,0.6,Arrowhead[]}}],Arrow/@datas}],AspectRatio->Automatic,PlotRangePadding->0.2,FrameTicks->None,ImageSize->120]]

Physical Optics

Physical optics is the wave mechanics of light (light propagates in the spacetime as a wave)

Its basic principle is Huygens’ Principle

Interference effect: contributions from different paths must be collected and summed up

(Subscript[ψ, B])=(∫_(A→B))(Subscript[ψ, A])(e^(i Θ(A→B))).

The accumulated phase Θ is determined by the propagation time × the frequency of light

Θ=ω T=(ω/c)L.

The phase is proportional to the optical path length (given that the light propagates with a fixed frequency).

p(x)=((|ψ(x)|)^2).

From Fermat to Huygens

Particle mechanics defines the action S in the variational principle δ S=0.

Wave mechanics defines the phase Θ in the wavelet propagator (e^(i Θ)).

Path Integral Quantization

Quantization of Matter

Classical Mechanics

S[x]=∫L(x,(OverDot[x]),t)dt.

(Subscript[(Subscript[δ S[x]|, x=(OverBar[x])])=δ∫L(x,(OverDot[x]),t)dt|, x=(OverBar[x])])=0.

(d/(d t))(((∂L)/(∂(OverDot[x]))))-((∂L)/(∂x))=0,

Nature may not have sufficient computational resources to carry out the classical mechanics precisely. => Classical mechanics might actually be realized only approximately as a stochastic global optimization, which is computationally more feasible.

Quantum mechanics takes a stochastic approach to optimize the action, which is more natural than the deterministic approach of classical mechanics, if we assume only limited computational resource is available to nature.

Optimization by Interference

f(x)=-(x^2)+2(x^4).

Plot[-x^2+2x^4,{x,-1,1},PlotStyle->Black,FrameLabel->{"\!\( x\)","\!\(f(x)\)"}]

Every point x is a legitimate guess of the solution.

Each point x is associated with an action f(x) (the objective function).

Raise the action f(x) to the exponent (as a phase): (e^(i f(x)/ℏ)) => call it a “probability amplitude” contributed by the point x.

A “Planck constant” ℏ=h/(2π) is introduced as a hyperparameter of the algorithm, to control “how quantum” the algorithm will be.

Contributions from all points must be collected and summed (integrated) up,

Z=(∫_(-∞)^∞)(e^(i f(x)/ℏ))dx.

dz=(e^(i f(x)/ℏ))dx.

dx controls the infinitesimal step size,

(e^(i f(x)/ℏ)) controls the direction to make the displacement,

displacement dz is accumulated to form the partition function,

Z≡∫dz.

For small h (classical limit)

Block[{f,h=0.001,dx,acc,Z1,Z2},
f[x_]:=-x^2+2x^4;
dx=0.01Sqrt[h];
acc=ReIm@Prepend[Accumulate[Table[Exp[2π I f[x]/h]dx,{x,dx/2,1/2+2Sqrt[2h],dx}]],0];
{Z1,Z2}={NIntegrate[Exp[2π I f[x]/h],{x,0,1/(2Sqrt[3])}],NIntegrate[Exp[2π I f[x]/h],{x,1/(2Sqrt[3]),∞}]};
Graphics[{{AbsoluteThickness[1],Line/@{acc,-acc}},{Arrowheads[0.08],
{Red,Arrow/@ReIm/@{{-Z1-Z2,-Z1},{-Z1,Z1},{Z1,Z1+Z2}},Text["\!\(Z\_\("<>#1<>"\)\)",ReIm@#2,#3]&@@@{{"-1/2",-Z1-Z2/2,{1,-1}},{"0",0,{-0.5,-1}},{"1/2",Z1+Z2/2,{-1,1}}}},
{Blue,Arrow/@ReIm/@{{-Z1-Z2,Z1+Z2}},
Text["\!\( Z\)",ReIm@(Z1+Z2)/2,{0,-0.6}]}}},
PlotLabel->Style["\!\(h="<>ToString[h]<>"\)",14,Black],ImageSize->160]
]

Z=(Subscript[Z, -1/2])+(Subscript[Z, 0])+(Subscript[Z, 1/2]),

Z can break up into three smaller contributions, which correspond to the contributions around the three stationary points: x=0,±1/2.

Around the stationary point, phase changes slowly (∂_x)f(x)∼0 => constructive interference => large contribution to the partition function.

The solutions of stationary points (classical solutions) emerge from interference due to their dominant contribution to the probability amplitude.

*More precisely, the partition function is actually evaluated with respect to the momentum k,

Z(k)≡∫dz (e^(i k x))≃(Subscript[Z, -1/2])(e^(-i k/2))+(Subscript[Z, 0])+(Subscript[Z, 1/2])(e^(i k/2)).

Then its Fourier spectrum (OverTilde[Z])(x)=∫dk Z(k)(e^(-i k x)) will reveal the saddle points.

Block[{ϵ=0.0001,ℏ=0.001,a=1/32,L=3,Z},
Z[k_]:=NIntegrate[Exp[(I-ϵ)(-x^2+2x^4)/ℏ]Exp[I k x],{x,-∞,∞}];
ListLinePlot[RotateLeft[#,Ceiling[Length[#]/2]]&[Abs[Fourier[Z/@Range[-π/a,π/a,2π/L]]]^2],DataRange->{-L/2,L/2},FrameLabel->{"\!\( x\)","\!\(\[LeftBracketingBar]Z\&~(x)\[RightBracketingBar]\^2\)"},PlotStyle->Black,PlotRange->All,AspectRatio->1/2,ImageSize->200]]

For intermediate h

Block[{f,h=0.1,dx,acc,Z1,Z2},
f[x_]:=-x^2+2x^4;
dx=0.01Sqrt[h];
acc=ReIm@Prepend[Accumulate[Table[Exp[2π I f[x]/h]dx,{x,dx/2,1/2+Sqrt[2h],dx}]],0];
{Z1,Z2}={NIntegrate[Exp[2π I f[x]/h],{x,0,1/(2Sqrt[3])}],NIntegrate[Exp[2π I f[x]/h],{x,1/(2Sqrt[3]),∞}]};
Graphics[{{AbsoluteThickness[1],Line/@{acc,-acc}},{Arrowheads[0.08],
{Red,Dashed,Arrow/@ReIm/@{{-Z1-Z2,-Z1},{-Z1,Z1},{Z1,Z1+Z2}},Text["\!\(Z\_\("<>#1<>"\)\)",ReIm@#2,#3]&@@@{{"-1/2",-Z1-Z2/2,{-1,-1}},{"0",0,{-1,-1}},{"1/2",Z1+Z2/2,{1,1}}}},
{Blue,Arrow/@ReIm/@{{-Z1-Z2,Z1+Z2}},Text["\!\( Z\)",0.9ReIm@(Z1+Z2),{0,-1}]}}},
PlotLabel->Style["\!\(h="<>ToString[h]<>"\)",14,Black],ImageSize->140]
]

The decomposition of Z into three subdominant amplitudes is not very well defined. => Quantum fluctuations start to smear out nearby stationary points.

For large h (quantum limit)

Block[{f,h=10,dx,acc,Z1,Z2},
f[x_]:=-x^2+2x^4;
dx=0.01Sqrt[h];
acc=ReIm@Prepend[Accumulate[Table[Exp[2π I f[x]/h]dx,{x,dx/2,1/2+Sqrt[h/2],dx}]],0];
{Z1,Z2}={NIntegrate[Exp[2π I f[x]/h],{x,0,1/(2Sqrt[3])}],NIntegrate[Exp[2π I f[x]/h],{x,1/(2Sqrt[3]),∞}]};
Graphics[{{AbsoluteThickness[1],Line/@{acc,-acc}},{Arrowheads[0.08],
{Blue,Arrow/@ReIm/@{{-Z1-Z2,Z1+Z2}},Text["\!\( Z\)",0.9ReIm@(Z1+Z2),{0,-1}]}}},
PlotLabel->Style["\!\(h="<>ToString[h]<>"\)",14,Black],ImageSize->160]
]

Stationary points are indistinguishable if quantum fluctuations are too large. => As if there is only one (approximate) stationary point around x=0.

If there is no sufficient resolution power, fine structures in the action landscape will be ignored by quantum mechanics. In this way, the computational complexity is controlled.

h=6.62607004×(10^(-34))J s.

h is very small (in our everyday unit) => our nature has a pretty high resolution of action => no need to worry about the resolution limit in the macroscopic world => classical mechanics works well.

However, in the microscopic world, nature’s resolution limit can be approached => “round-off error” may occur => one consequence is the quantization of atomic orbitals (discrete energy levels etc.).

Path Integral and Wave Function

The probability (Subscript[p, A→B]) for a particle to propagate from A to B is given by the square modulus of a complex number (Subscript[K, A→B]) called the transition amplitude

The transition amplitude is given by adding together the contributions of all paths x from A to B.

Block[{randpath},
randpath[p1_,p2_]:=BSplineCurve@Table[(1-t)p1+t p2+{0,t(1-t)RandomReal[{-1,1}]},{t,0,1,0.05}];
Graphics[{{Opacity[0.5],AbsoluteThickness[1],Table[{ColorData[0,i],randpath[{0,0},{1,0}]},{i,10}]},Point/@{{0,0},{1,0}},
Text["\!\( A\)",{0,0},{1.2,0}],Text["\!\( B\)",{1,0},{-1.2,0}]}]]

The contribution of each particular path is proportional to (e^(i S[x]/ℏ)), where S[x] is the action of the path x.

(Subscript[K, A→B])∼(e^(i S[(OverBar[x])]/ℏ)).

(Subscript[K, A→B])=(∫_C)(Subscript[K, A→C])(Subscript[K, C→B]).

(Subscript[K, ((Subscript[x, 0]),(Subscript[t, 0]))->((Subscript[x, N]),(Subscript[t, N]))])=∫d(Subscript[x, 1])…d(Subscript[x, N-1])(Subscript[K, ((Subscript[x, 0]),(Subscript[t, 0]))→((Subscript[x, 1]),(Subscript[t, 1]))])… (Subscript[K, ((Subscript[x, N-1]),(Subscript[t, N-1]))→((Subscript[x, N]),(Subscript[t, N]))]).

ψ((Subscript[x, k+1]),(Subscript[t, k+1]))=∫d(Subscript[x, k])(Subscript[K, ((Subscript[x, k]),(Subscript[t, k]))->((Subscript[x, k+1]),(Subscript[t, k+1]))])ψ((Subscript[x, k]),(Subscript[t, k])).

ψ((Subscript[x, k+1]),(Subscript[t, k+1]))∝∫ⅅ[x]exp((i/ℏ)S[x])ψ((Subscript[x, k]),(Subscript[t, k])),

for each given initial point (Subscript[x, k]), integrate over paths x(t) subject to the boundary conditions x((Subscript[t, k]))=(Subscript[x, k]) and x((Subscript[t, k+1]))=(Subscript[x, k+1]),

finally integrate over choices of initial point (Subscript[x, k]).

Deriving the Schrödinger Equation

Action in a Time Slice

x(t)=(Subscript[x, 0])+v t,

v=(((Subscript[x, 1])-(Subscript[x, 0]))/((Subscript[t, 1])-(Subscript[t, 0])))=(((Subscript[x, 1])-(Subscript[x, 0]))/(δ t)).

S[x]=(1/2)((m((((Subscript[x, 1])-(Subscript[x, 0]))/(δ t))))^2)δ t=(m/(2δ t))((((Subscript[x, 1])-(Subscript[x, 0])))^2).

Path Integral in a Time Slice

ψ((Subscript[x, 1]),t+δ t)∝∫d(Subscript[x, 0])exp((i/ℏ)S[x])ψ((Subscript[x, 0]),t)
=∫d(Subscript[x, 0])exp(((i m)/(2ℏ δ t))((((Subscript[x, 1])-(Subscript[x, 0])))^2))ψ((Subscript[x, 0]),t).

The proportional sign “∝” implies that the normalization factor is not determined yet. (It will be determined later.)

ψ((Subscript[x, 0]),t)=ψ((Subscript[x, 1])+a,t)
=ψ((Subscript[x, 1]),t)+a ψ'((Subscript[x, 1]),t)+((a^2)/(2!))ψ''((Subscript[x, 1]),t)+((a^3)/(3!))(ψ^((3)))((Subscript[x, 1]),t)+…
=(∑_(n=0)^∞)((a^n)/(n!))(∂_(Subscript[x, 1])^n)ψ((Subscript[x, 1]),t).

ψ((Subscript[x, 1]),t+δ t)∝(∑_(n=0)^∞)∫da exp(((i m)/(2ℏ δ t))(a^2))((a^n)/(n!))(∂_(Subscript[x, 1])^n)ψ((Subscript[x, 1]),t).

The idea is that the time-evolved wave function can be expressed as the original wave function “dressed” by its (different orders of) derivatives.

Plot[{Exp[-x^2/2],-x Exp[-x^2/2],(x^2-1)Exp[-x^2/2]},{x,-5,5},PlotRange->All,Epilog->{{#1,Text["\!\("<>#2<>" ψ(x)\)",#3]}&@@@{{Blue,"",{1.8,0.9}},{Red,"∂\_x",{3.5,-0.5}},{Green,"∂\_x\%2",{2.2,-0.9}}}},FrameLabel->{"\!\(x \)","\!\(∂\_x\%n ψ(x)\)"},ImageSize->200]

For example, ψ(x) is a wave packet.

ψ(x)+λ ψ'(x): shift the wave packet around.

ψ(x)+λ ψ''(x): expand or shrink the wave packet.

Locality of Physics: the time evolution should only involve local modifications of the wave function ψ(x) (within the light-cone) in each step.

Computing the Coefficients (Subscript[λ, n])

(Subscript[λ, n])=((1+(((-1))^n))/2)((Sqrt[π])/((2^n)Γ(1+(n/2))))(((-((i m)/(2ℏ δ t))))^(-((1+n)/2))).

FunctionExpand[Integrate[Exp[I c a^2]a^n/n!,{a,-∞,∞}, GenerateConditions->False]]

Evaluate the integral for (Subscript[λ, n]).

The first term (1+(((-1))^n))/2 just discriminates even and odd n.

((1+(((-1))^n))/2)=({{{, ({{1, if n∈even,}, {0, if n∈odd.}})}})

So as long as n∈odd, (Subscript[λ, n])=0. We only need to consider the case of even n.

For even n, the first several (Subscript[λ, n]) are given by

(Subscript[λ, 0])=(Sqrt[π])(((-((i m)/(2ℏ δ t))))^(-1/2)),
(Subscript[λ, 2])=((Sqrt[π])/4)(((-((i m)/(2ℏ δ t))))^(-3/2))=((i )/4)(((2ℏ δ t)/m))(Subscript[λ, 0]),
(Subscript[λ, 4])=((Sqrt[π])/32)(((-((i m)/(2ℏ δ t))))^(-5/2))=-(1/32)(((((2ℏ δ t)/m)))^2)(Subscript[λ, 0]),
…

Block[{λ},
λ=Association@Table[
n->Sqrt[π]/(2^n Gamma[1+n/2])(-I c)^(-(1+n)/2),{n,0,4,2}];
{λ,λ/λ[0]}]

The first several (Subscript[λ, n]) for even n.

Determining the Normalization

ψ(x,t+δ t)∝(Subscript[λ, 0])(1+(i/4)(((2ℏ δ t)/m))(∂_x^2)-(1/32)(((((2ℏ δ t)/m)))^2)(∂_x^4)+…)ψ(x,t).

If we take δ t=0, all higher order terms vanishes,

ψ(x,t)∝(Subscript[λ, 0])ψ(x,t).

So obviously, the normalization factor should be such to cancelled out (Subscript[λ, 0]).

ψ(x,t+δ t)=(1+(i/4)(((2ℏ δ t)/m))(∂_x^2)-(1/32)(((((2ℏ δ t)/m)))^2)(∂_x^4)+…)ψ(x,t).

Taking the Limit of δ t->0

(∂_t)ψ(x,t)=(lim_(δ t->0))((ψ(x,t+δ t)-ψ(x,t))/(δ t))
=(lim_(δ t->0))(1/(δ t))((i/4)(((2ℏ δ t)/m))(∂_x^2)-(1/32)(((((2ℏ δ t)/m)))^2)(∂_x^4)+…)ψ(x,t)

Only the first term survives under the limit δ t->0,

(∂_t)ψ(x,t)=((i ℏ)/(2m))(∂_x^2)ψ(x,t).

All the higher order terms will have higher powers in δ t, so they should all vanish under the limit δ t->0.

Adding Potential Energy

Δ S=-V(x)δ t.

ψ(x,t+δ t)=(e^(i Δ S/ℏ))(Subscript[ψ, 0])(x,t+δ t)
=(e^(-i V(x)δ t/ℏ))(Subscript[ψ, 0])(x,t+δ t)
=(1-(i/ℏ)V(x)δ t+…)(Subscript[ψ, 0])(x,t+δ t),

ψ(x,t+δ t)=(1-(i/ℏ)V(x)δ t+…)(1+(i/4)(((2ℏ δ t)/m))(∂_x^2)+…)ψ(x,t)
=(1+(i/4)(((2ℏ δ t)/m))(∂_x^2)-(i/ℏ)V(x)δ t+…)ψ(x,t).

(∂_t)ψ(x,t)=((i ℏ)/(2m))(∂_x^2)ψ(x,t)-(i/ℏ)V(x)ψ(x,t),

Single-Particle Quantum Mechanics

Wave Mechanics v.s. Matrix Mechanics

Functions as Vectors

ψ(x)∼(({{⋯, ψ(0), ⋯, ψ(0.01), ⋯, ψ(0.5), ⋯}}))ᵀ.

Elements of the vector are labeled by real numbers x∈ℝ (instead of integers). The vector is like a look-up table representation of the function.

The ket state:

(Ket[ψ])≏ψ(x).

ψ:ℝ→ℂ is a complex function in general.

The bra state:

(Bra[ψ])≏(SuperStar[ψ])(x).

Inner product of bra and ket

as a functional generalization of (BraKet[ϕ, ψ])=(∑_i)(Subscript[ϕ, i]^( * ))(Subscript[ψ, i]).

Normalized state: (Ket[ψ]) is normalized iff

(BraKet[ψ, ψ])=∫dx (SuperStar[ψ])(x)ψ(x)=∫dx ((|ψ(x)|)^2)=1.

Orthogonal states: two states (Ket[ϕ]) and (Ket[ψ]) are orthogonal iff

(BraKet[ϕ, ψ])=∫dx (SuperStar[ϕ])(x)ψ(x)=0.

It can be considered as the limit of Gaussians with σ->0

δ(x)=(lim_(σ->0))(1/((Sqrt[2π])σ))(e^(-((x^2)/(2(σ^2))))).

Block[{σs={0.05,0.2,1.},sty=Style[#,FontFamily->"CMU"]&},
Plot[Evaluate@Table[Exp[-x^2/(2σ^2)]/(Sqrt[2π]σ),{σ,σs}],{x,-3,3},PlotRange->All,FrameLabel->{"\!\( x\)","\!\(f(x)\)"},PlotLegends->LineLegend[Automatic,sty/@σs,LegendLabel->sty@"\!\(σ=\)",LegendMargins->1],ImageSize->180]]

Loosely speaking

δ(x)=({{{, ({{0, if x≠0,}, {∞, if x=0  (ill–defined).}})}})

The area under the curve remains unity as the limit is taken, i.e. ∫δ(x)dx=1, as a functional generalization of (∑_i)(Subscript[δ, i j])=1.

Multiplying δ(x-a) with an ordinary function ψ(x) is the same as multiplying ψ(a), i.e. δ(x-a)ψ(x)=ψ(a)δ(x-a), because the product is zero everywhere except at point a. In particular,

∫δ(x-a)ψ(x)dx=ψ(a).

This can be thought as the defining property of the Dirac δ-function: convolution of δ(x-a) with any function ψ(x) picks out the value of the function ψ(a) at point a. It is a functional generalization of (∑_j)(Subscript[δ, i j])(Subscript[ψ, j])=(Subscript[ψ, i]).

(Ket[(Subscript[x, 1])])≏δ(x-(Subscript[x, 1])).

(Subscript[x, 1]) labels the basis state,

x is a dummy variable of the corresponding wave function.

The wave function δ(x-(Subscript[x, 1])) describes the state that the particle is at a definite position (Subscript[x, 1]). It can be prepared by measuring the position and then post-select based on the measurement outcome.

(BraKet[(Subscript[x, 1]), (Subscript[x, 2])])=∫δ(x-(Subscript[x, 1]))δ(x-(Subscript[x, 2]))dx=δ((Subscript[x, 1])-(Subscript[x, 2])),

Thus (Ket[x]) (x∈ℝ) for a set of orthonormal basis of the Hilbert space of a particle (the Hilbert space dimension is infinite) => the single-particle Hilbert space.

Any state in the single-particle Hilbert space is a linear superposition of these basis states

as a functional generalization of (Ket[ψ])=(∑_i)(Subscript[ψ, i])(Ket[i]).

The wave function of a state (Ket[ψ]) can be extracted by the inner product with position basis

(BraKet[x, ψ])=∫δ(x'-x)ψ(x')dx'=ψ(x),

as a functional generalization of (Subscript[ψ, i])=(BraKet[i, ψ]).

Operators as Matrices

Operator acting on a state (Ket[ψ]),

(OverHat[M])(Ket[ψ])=∫d(Subscript[x, 1])d(Subscript[x, 2])d(Subscript[x, 3])(Ket[(Subscript[x, 1])])M((Subscript[x, 1]),(Subscript[x, 2]))(BraKet[(Subscript[x, 2]), (Subscript[x, 3])])ψ((Subscript[x, 3]))
=∫d(Subscript[x, 1])d(Subscript[x, 2])d(Subscript[x, 3])(Ket[(Subscript[x, 1])])M((Subscript[x, 1]),(Subscript[x, 2]))δ((Subscript[x, 2])-(Subscript[x, 3]))ψ((Subscript[x, 3]))
=∫d(Subscript[x, 1])d(Subscript[x, 2])(Ket[(Subscript[x, 1])])M((Subscript[x, 1]),(Subscript[x, 2]))ψ((Subscript[x, 2])).

If we define a new wave function ϕ via the following convolution

ϕ((Subscript[x, 1]))=∫d(Subscript[x, 2])M((Subscript[x, 1]),(Subscript[x, 2]))ψ((Subscript[x, 2])),

where M((Subscript[x, 1]),(Subscript[x, 2])) is the convolution kernel, we can write

(OverHat[M])(Ket[ψ])=(Ket[ϕ])=∫d(Subscript[x, 1])(Ket[(Subscript[x, 1])])ϕ((Subscript[x, 1])).

So an operator does change the state in general (unless it is the identity operator).

The identity operator is represented by the δ-function convolution kernel M((Subscript[x, 1]),(Subscript[x, 2]))=δ((Subscript[x, 1])-(Subscript[x, 2])), because ∫d(Subscript[x, 2])δ((Subscript[x, 1])-(Subscript[x, 2]))ψ((Subscript[x, 2]))=ψ((Subscript[x, 1])) does not really change the wave function. So the identity operator can be written as

𝟙=∫d(Subscript[x, 1])d(Subscript[x, 2])(Ket[(Subscript[x, 1])])δ((Subscript[x, 1])-(Subscript[x, 2]))(Bra[(Subscript[x, 2])])=∫dx(Ket[x])(Bra[x]),

a functional generalization of (∑_i)(Ket[i])(Bra[i])=𝟙.

Since the operator is specified by a two-variable function M((Subscript[x, 1]),(Subscript[x, 2])), it can be viewed as an infinite-dimensional matrix

(OverHat[M])≏M((Subscript[x, 1]),(Subscript[x, 2]))   or  (({{⋱, ⋮, ⋰}, {⋯, M((Subscript[x, 1]),(Subscript[x, 2])), ⋯}, {⋰, ⋮, ⋱}})).

(Subscript[x, 1]), (Subscript[x, 2]) are row and column indices (indexed by real numbers).

(SuperDagger[(OverHat[M])])=∫d(Subscript[x, 1])d(Subscript[x, 2])(Ket[(Subscript[x, 1])])(SuperStar[M])((Subscript[x, 2]),(Subscript[x, 1]))(Bra[(Subscript[x, 2])]).

Hermitian operator: (SuperDagger[(OverHat[L])])=(OverHat[L]). Hermitian operators correspond to physical observables.

The expectation value of (OverHat[L]) on the state (Ket[ψ]) is given by

Unitary operator: (SuperDagger[(OverHat[U])])(OverHat[U])=(OverHat[U])(SuperDagger[(OverHat[U])])=𝟙.

Momentum Operator

(∂_x)=∫d(Subscript[x, 1])d(Subscript[x, 2])(Ket[(Subscript[x, 1])])δ'((Subscript[x, 1])-(Subscript[x, 2]))(Bra[(Subscript[x, 2])]).

δ'(x)=(∂_x)δ(x) is the first derivative of the Dirac δ-function. Think in terms of the limit

δ'(x)=(lim_(σ->0))((-x)/((Sqrt[2π])(σ^3)))(e^(-((x^2)/(2(σ^2))))).

Block[{σs={0.1,0.2},sty=Style[#,FontFamily->"CMU"]&},
Plot[Evaluate@Table[-x Exp[-x^2/(2σ^2)]/(Sqrt[2π]σ^3),{σ,σs}],{x,-3,3},PlotRange->All,FrameLabel->{"\!\( x\)","\!\(δ\^′(x)\)"},PlotLegends->LineLegend[Automatic,sty/@σs,LegendLabel->sty@"\!\(σ=\)",LegendMargins->1],ImageSize->180]]

δ'((Subscript[x, 1])-(Subscript[x, 2])) can be either understood as (∂_(Subscript[x, 1]))δ((Subscript[x, 1])-(Subscript[x, 2])) or as -(∂_(Subscript[x, 2]))δ((Subscript[x, 1])-(Subscript[x, 2])). Under convolution,

∫d(Subscript[x, 2])δ'((Subscript[x, 1])-(Subscript[x, 2]))ψ((Subscript[x, 2]))
=∫d(Subscript[x, 2])(-(∂_(Subscript[x, 2]))δ((Subscript[x, 1])-(Subscript[x, 2])))ψ((Subscript[x, 2]))
=∫d(Subscript[x, 2])δ((Subscript[x, 1])-(Subscript[x, 2]))((∂_(Subscript[x, 2]))ψ((Subscript[x, 2])))
=(∂_(Subscript[x, 1]))ψ((Subscript[x, 1])),

so the kernel δ'((Subscript[x, 1])-(Subscript[x, 2])) indeed implements differentiation under convolution.

In the matrix form,

(∂_x)(Ket[ψ])≏(lim_(δ x->0))(1/(2δ x))(({{⋱, ⋱,  ,  ,  }, {⋱, 0, 1,  ,  }, { , -1, 0, 1,  }, { ,  , -1, 0, ⋱}, { ,  ,  , ⋱, ⋱}}))(({{⋮}, {ψ(x-δ x)}, {ψ(x)}, {ψ(x+δ x)}, {⋮}}))
=(lim_(δ x->0))((ψ(x+δ x)-ψ(x-δ x))/(2δ x))≏(Ket[(∂_x)ψ]).

Note: to discretize δ'((Subscript[x, 1])-(Subscript[x, 2])) without losing its essential meaning, we can consider

Block[{L=8,pts},
pts=Table[{x,If[Abs[x]==1,-x,0]},{x,-L,L}];
Graphics[{{Text["\!\(δ\^′(x\_1-x\_2)∝\)",{-L-1,0},{1,0}]},{AbsoluteThickness[0.8],Arrow[{0,#}&/@{-1.2,1.2}],Arrow[{#,0}&/@{-L-1,L+2}],Text["\!\(x\_1-x\_2\)",{L+1,0},{0,-1.2}]},{Blue,Line[pts]},Text[Style[Last@#,12],#]&/@pts},AspectRatio->0.3,ImageSize->260]]

Higher order derivatives: just multiply the matrix n times.

(∂_x^n)≏(δ^((n)))((Subscript[x, 1])-(Subscript[x, 2]))  or  (lim_(δ x->0))(1/(((2δ x))^n))(((({{⋱, ⋱,  ,  ,  }, {⋱, 0, 1,  ,  }, { , -1, 0, 1,  }, { ,  , -1, 0, ⋱}, { ,  ,  , ⋱, ⋱}})))^n).

(SuperDagger[((∂_x))])=∫d(Subscript[x, 1])d(Subscript[x, 2])(Ket[(Subscript[x, 1])])(δ^(′* ))((Subscript[x, 2])-(Subscript[x, 1]))(Bra[(Subscript[x, 2])])
=-∫d(Subscript[x, 1])d(Subscript[x, 2])(Ket[(Subscript[x, 1])])δ'((Subscript[x, 1])-(Subscript[x, 2]))(Bra[(Subscript[x, 2])])
=-(∂_x).

ψ∼(e^(i Θ))∼(e^(i S/ℏ)),

(OverHat[p])ψ=-i ℏ(∂_x)(e^(i S/ℏ))∼-i ℏ(((i (∂_x)S)/ℏ))(e^(i S/ℏ))∼((∂_x)S)ψ.

Position Operator

The position operator (OverHat[x]) acting on a state (Ket[ψ])=∫dx(Ket[x])ψ(x)

(OverHat[x])(Ket[ψ])=∫dxdx'(Ket[x])x (BraKet[x, x'])ψ(x')
=∫dxdx'(Ket[x])x δ(x-x')ψ(x')
=∫dx (x ψ(x))(Ket[x]).

In terms of the wave function ψ(x), the position operator basically multiplies the wave function by the position x:

ψ(x)(Overscript[->, (OverHat[x]) ])x ψ(x).

A sloppy notation:

(OverHat[x])ψ(x)=x ψ(x).

The momentum operator (OverHat[p]) acting on a state (Ket[ψ])=∫dx(Ket[x])ψ(x)

(OverHat[p])(Ket[ψ])=∫dx (Ket[x])(-i ℏ(∂_x)ψ(x)).

Another sloppy notation:

(OverHat[p])ψ(x)=-i ℏ(∂_x)ψ(x).

Uncertainty Relation

(OverHat[x])(OverHat[p])ψ(x)=-i ℏ x(∂_x)ψ(x),
(OverHat[p])(OverHat[x])ψ(x)=-i ℏ(∂_x)(x ψ(x))=-i ℏ ψ(x)-i ℏ x (∂_x)ψ(x),

[(OverHat[x]),(OverHat[p])]ψ(x)=((OverHat[x])(OverHat[p])-(OverHat[p])(OverHat[x]))ψ(x)
=-i ℏ x(∂_x)ψ(x)+i ℏ ψ(x)+i ℏ x (∂_x)ψ(x)
=i ℏ ψ(x),

If the particle has a precise position, i.e. (std x)->0, its momentum must fluctuate infinitely strong, i.e. (std p)->∞.

If we want to probe smaller and smaller structures of our space, we must use particles (say photons) with larger and larger momentum, until the energy E=c p of the photon becomes so large that the photon itself collapses into a black hole under its own gravity. => Quantum mechanics imposes a fundamental resolution limit of the space: the Planck length

(Subscript[ℓ, P])=(Sqrt[((ℏ G)/(c^3))])≈1.616229(38)×(10^(-35))m.

Dynamics and Symmetry

Hamiltonian and Time Evolution

H=((p^2)/(2m))+V(x).

(OverHat[H])=(((OverHat[p])^2)/(2m))+V((OverHat[x]))
=-((ℏ^2)/(2m))(∂_x^2)+V((OverHat[x])).

By V((OverHat[x])) we mean

V((OverHat[x]))=∫dx(Ket[x])V(x)(Bra[x]).

This is always how we define a function of an operator. Its action on a wave function ψ(x) (in the position basis) is simply to multiply it by V(x), sloppy notation:

V((OverHat[x]))ψ(x)=V(x)ψ(x).

ψ∼(e^(i Θ))∼(e^(i S/ℏ)),

(OverHat[H])ψ=i ℏ(∂_t)(e^(i S/ℏ))∼i ℏ(((i (∂_t)S)/ℏ))(e^(i S/ℏ))∼(-(∂_t)S)ψ.

Momentum and Space Translation

Acting on a wave function ψ(x)

(OverHat[T])(a)ψ(x)=(e^(i (OverHat[p])a /ℏ))ψ(x)
=exp(a (∂_x))ψ(x)
=(𝟙+a (∂_x)+((a^2)/(2!)) (∂_x^2)+((a^3)/(3!))(∂_x^3)+…)ψ(x)
=ψ(x)+a ψ'(x)+((a^2)/(2!)) ψ''(x)+((a^3)/(3!))(ψ^((3)))(x)+…
=ψ(x+a).

So the unitary operator (OverHat[T])(a) implements the space translation x->x+a, it is called the space translation operator.

Another equivalent definition of (OverHat[T])(a) is

Such that given the state (Ket[ψ])=∫dx ψ(x)(Ket[x])

(OverHat[T])(a)(Ket[ψ])=∫dxdx'(Ket[x-a])(BraKet[x, x'])ψ(x')
=∫dxdx'(Ket[x-a])δ(x-x')ψ(x')
=∫dx ψ(x)(Ket[x-a])
=∫dx ψ(x+a)(Ket[x]).

The inverse translation should be given by the Hermitian conjugate,

((OverHat[T])^(-1))(a)=(SuperDagger[(OverHat[T])])(a)=∫dx(Ket[x])(Bra[x-a])=∫dx(Ket[x+a])(Bra[x])=T(-a).

Symmetry and Conservation Laws

the position operator (OverHat[x]) → will shift the position

(OverHat[T])(a)(OverHat[x])(SuperDagger[(OverHat[T])])(a)
=∫d(Subscript[x, 1])(Ket[(Subscript[x, 1])-a])(Bra[(Subscript[x, 1])])∫d(Subscript[x, 2])(Ket[(Subscript[x, 2])])(Subscript[x, 2])(Bra[(Subscript[x, 2])])∫d(Subscript[x, 3])(Ket[(Subscript[x, 3])])(Bra[(Subscript[x, 3])-a])
=∫d(Subscript[x, 1])d(Subscript[x, 2])d(Subscript[x, 3])(Ket[(Subscript[x, 1])-a])(BraKet[(Subscript[x, 1]), (Subscript[x, 2])])(Subscript[x, 2])(BraKet[(Subscript[x, 2]), (Subscript[x, 3])])(Bra[(Subscript[x, 3])-a])
=∫d(Subscript[x, 1])(Ket[(Subscript[x, 1])-a])(Subscript[x, 1])(Bra[(Subscript[x, 1])-a])
=∫dx(Ket[x])(x+a)(Bra[x])
=∫dx(Ket[x])x(Bra[x])+a∫dx(Ket[x])(Bra[x])
=(OverHat[x])+a 𝟙.

the momentum operator (OverHat[p]) → will do nothing

(OverHat[T])(a)(OverHat[p])(SuperDagger[(OverHat[T])])(a)
=(e^(i (OverHat[p])a /ℏ))(OverHat[p])(e^(-i (OverHat[p])a /ℏ))
=(e^(i (OverHat[p])a /ℏ))(e^(-i (OverHat[p])a /ℏ))(OverHat[p])
=(OverHat[p]).

the Hamiltonian (OverHat[H]) → will only translate the potential profile

(OverHat[T])(a)(OverHat[H])(SuperDagger[(OverHat[T])])(a)
=(OverHat[T])(a)((((OverHat[p])^2)/(2m))+V((OverHat[x])))(SuperDagger[(OverHat[T])])(a)
=(((OverHat[p])^2)/(2m))+V((OverHat[x])+a).

V(x+a)=V(x),

(OverHat[T])(a)(OverHat[H])(SuperDagger[(OverHat[T])])(a)=(e^(i (OverHat[p])a /ℏ))(OverHat[H])(e^(-i (OverHat[p])a /ℏ))
=(𝟙+((i (OverHat[p])a)/ℏ)+…)(OverHat[H])(𝟙-((i (OverHat[p])a)/ℏ)+...)
=(OverHat[H])+((i a)/ℏ)[(OverHat[p]),(OverHat[H])]+𝒪((a^2))=(OverHat[H]),

[(OverHat[p]),(OverHat[H])]=0.

i ℏ(∂_t)(OverHat[p])(t)=[(OverHat[p])(t),(OverHat[H])]=0,

Space translation symmetry ⇔ Momentum conservation

Time translation symmetry ⇔ Energy conservation

(OverHat[H])=(((OverHat[p])^2)/(2m))+V((OverHat[x]))(Overscript[→, m->∞])(OverHat[H])=V((OverHat[x])).

Wave-Particle Duality

Momentum Basis

(OverHat[p])(Ket[p])=p(Ket[p]).

Eigenstates (Ket[p]) are labeled by momentum eigenvalues p∈ℝ.

Any state in the single-particle Hilbert space can is a linear superposition of the momentum basis states,

Given the state (Ket[(OverTilde[ψ])]), the probability density to observe the particle with momentum p is

The normalization factor 1/(Sqrt[2π ℏ]) is just a matter of convention.

(OverHat[p])(Ket[p])=(1/(Sqrt[2π ℏ]))∫dx (-i ℏ(∂_x)(e^(i p x/ℏ)))(Ket[x])
=(1/(Sqrt[2π ℏ]))∫dx (p (e^(i p x/ℏ)))(Ket[x])
=p(Ket[p]).

(OverHat[H])=(((OverHat[p])^2)/(2m)),

(OverHat[H])(Ket[p])=((p^2)/(2m))(Ket[p]).

(BraKet[x, p])=(1/(Sqrt[2π ℏ]))(e^(i p x/ℏ)),

Fourier Transform

𝟙=∫dxdp(Ket[x])(BraKet[x, p])(Bra[p])=(1/(Sqrt[2π ℏ]))∫dxdp(Ket[x])(e^(i p x/ℏ))(Bra[p]),
𝟙=∫dxdp(Ket[p])(BraKet[p, x])(Bra[x])=(1/(Sqrt[2π ℏ]))∫dxdp(Ket[p])(e^(-i p x/ℏ))(Bra[x]).

∫dx ψ(x)(Ket[x])
=(1/(Sqrt[2π ℏ]))∫dxdp(Ket[p])(e^(-i p x/ℏ))(Bra[x])∫dx' ψ(x')(Ket[x'])
=(1/(Sqrt[2π ℏ]))∫dxdpdx'(Ket[p])(e^(-i p x/ℏ))ψ(x')δ(x-x')
=(1/(Sqrt[2π ℏ]))∫dxdp(Ket[p])(e^(-i p x/ℏ))ψ(x)
=∫dp (OverTilde[ψ])(p)(Ket[p]),

In Eq. (), the same state is written in two different ways:

as a superposition of position basis ∫dx ψ(x)(Ket[x]),

as a superposition of momentum basis ∫dp (OverTilde[ψ])(p)(Ket[p]),

The superposition coefficients ψ(x) and (OverTilde[ψ])(p) will be related by Fourier transforms, for the two descriptions to be equivalent.

Sometimes we call ψ(x) the position (real) space wave function and (OverTilde[ψ])(p) the momentum space wave function.

This is an example of duality in physics: two seemly different descriptions actually correspond to the same physics.

The Fourier transform is also a special case of the more general representation transformation, which transforms between two arbitrary sets of basis.

Quantum Planar Rotor

Rotor Basis

DynamicModule[{x=0.3,dx=0.01,dyn=False},
Dynamic[If[dyn,x=Mod[x+dx,1]];EventHandler[Deploy[Row[{Graphics[{Line[{{0,0},{1,0}}],Translate[Line[Offset/@{{0,-2},{0,2}}],{#,0}]&/@{0,1},AbsolutePointSize[6],Point[{x,0}],Text["\!\( x\)",{x,0},{0,1.2}],Text["0",{0,0},{0,1.2}],Text["1",{1,0},{0,1.2}]},PlotRange->{{-0.2,1.2},{-1,1}},AspectRatio->0.5,ImageSize->100],Graphics[{Circle[{0,0},1],AbsolutePointSize[6],Point[ReIm@Exp[2π I x]],{AbsoluteThickness[0.8],{Dashed,Line[ReIm/@{0,Exp[2π I #]}]&/@{0,x}},Circle[{0,0},0.15,{0,2π x}],Text["θ",ReIm[0.3 Exp[π I x]]]},Text["0",{1.1,0},{-1,-0.5}],Text["2π",{1.1,0},{-1,0.5}]},PlotRange->1.5,ImageSize->100]},Alignment->Center]],{"MouseClicked":>(dyn=Not[dyn])}]]]

x∈[0,1) with periodic boundary condition, i.e. x=1 is equivalent to x=0.

Or in terms of angular variable θ=2π x, s.t. θ∈[0,2π) with θ=2π equivalent to θ=0.

(Ket[θ]) describes the state that the rotor is at a definite angular position θ.

All states (Ket[θ]) form a orthonormal basis

Any state of the planar rotor can be expanded as a linear superposition of the rotor basis states

Hereinafter, the integration of any angular variable θ is always assumed to be from 0 to 2π, as (∫_0^(2π))dθ.

The periodicity of θ => (Ket[θ]) and (Ket[θ±2π]) are the same state (just different names). Any physical state/operator should be invariant under θ->θ±2π.

(e^(i (Subscript[θ, 1])))(e^(i (Subscript[θ, 2])))=(e^(i ((Subscript[θ, 1])+(Subscript[θ, 2])))).

Rotation and Angular Momentum

The operator (OverHat[N]) can be found via

(OverHat[N])=(lim_(α->0))(-i (∂_α)(OverHat[R])(α))
=(lim_(α->0))(-i (∂_α)∫dθ(Ket[θ-α])(Bra[θ]))
=(lim_(α->0))(-i (∂_α)∫d(Subscript[θ, 1])d(Subscript[θ, 2])(Ket[(Subscript[θ, 1])])δ((Subscript[θ, 1])-(Subscript[θ, 2])+α)(Bra[(Subscript[θ, 2])]))
=(lim_(α->0))∫d(Subscript[θ, 1])d(Subscript[θ, 2])(Ket[(Subscript[θ, 1])])(-i δ'((Subscript[θ, 1])-(Subscript[θ, 2])+α))(Bra[(Subscript[θ, 2])])
=∫d(Subscript[θ, 1])d(Subscript[θ, 2])(Ket[(Subscript[θ, 1])])(-i δ'((Subscript[θ, 1])-(Subscript[θ, 2])))(Bra[(Subscript[θ, 2])])

Acting (OverHat[N]) on a state (Ket[ψ])=∫dθ ψ(θ)(Ket[θ]),

(OverHat[N])(Ket[ψ])=∫dθdθ'(Ket[θ])(-i δ'(θ-θ'))ψ(θ')
=∫dθdθ'(Ket[θ])(-i δ(θ-θ')(∂_(θ'))ψ(θ'))
=∫dθ (-i (∂_θ)ψ(θ))(Ket[θ]),

the effect is like (in sloppy notation)

(OverHat[N])ψ(θ)=-i (∂_θ)ψ(θ).

(OverHat[L])=(OverHat[N])ℏ,

Angular Momentum Quantization

(OverHat[N])(Ket[N])=N(Ket[N]),

(Ket[N])=∫dθ(Ket[θ])(BraKet[θ, N]),

-i(∂_θ)(BraKet[θ, N])=N(BraKet[θ, N])=>(BraKet[θ, N])∝(e^(i N θ)).

(Ket[N])=(OverHat[R])(2π)(Ket[N])
=(e^(2π i (OverHat[N])))(Ket[N])
=(e^(2π i N))(Ket[N]),

If the coordinate is compact (like θ), the momentum will be quantized (like N).

The integer N is also called the angular momentum quantum number. As we restore the dimension, the angular momentum is quantized to N ℏ (in unit of ℏ).

(Ket[N=0]) state: a equal weight and equal phase superposition of all rotor basis

(Ket[N=0])=(1/(Sqrt[2π]))∫dθ (Ket[θ]).

Zero angular momentum => the rotor is “static” (but not in the classical sense).

The probability to find the rotor at angle θ: p(θ)=1/(2π) => the rotor rests everywhere with equal probability => manifesting the uncertainty relation and quantum fluctuations.

N>0 states => positive angular momentum => counterclockwise rotating rotors.

N<0 states => negative angular momentum => clockwise rotating rotors.

Representation Transformation

Unlike the rotor basis, the angular momentum basis is discrete. Its orthonormality implies

(BraKet[(Subscript[N, 1]), (Subscript[N, 2])])=(Subscript[δ, (Subscript[N, 1])(Subscript[N, 2])]).

Its completeness implies

𝟙=(∑_(N∈ℤ))(Ket[N])(Bra[N]).

The two sets of basis are related by

The basis transformations are implemented by Fourier transforms

𝟙=(1/(Sqrt[2π]))(∑_(N∈ℤ))(∫_(U(1)))dθ (Ket[θ])(e^(i N θ))(Bra[N]),
𝟙=(1/(Sqrt[2π]))(∑_(N∈ℤ))(∫_(U(1)))dθ (Ket[N])(e^(-i N θ))(Bra[θ]).

Free Planar Rotor

(OverHat[H])=(1/(2I))((OverHat[L])^2)=((ℏ^2)/(2I))((OverHat[N])^2)=-((ℏ^2)/(2I))(∂_θ^2),

The energy has a quadratic dependence on the quantum number N,

Block[{M=6},ListLinePlot[Table[{Ν,Ν^2/2},{Ν,-M,M}],PlotRangePadding->Scaled[0.03],GridLines->{Range[-M,M],Range[0,M]^2/2},PlotStyle->Black,PlotMarkers->Graphics[{EdgeForm[Black],White,Disk[{0,0},Offset[{2,2}]]}],
FrameLabel->{"\!\( N\)","\!\(E\_N\)"},ImageSize->200]]

The eigenenergies are discrete => energy levels.

The lowest energy eigenstate (Ket[0]) is called the ground state. All the other higher energy eigenstates (Ket[N]) (for N=±1,±2,…) are excited states.

The ground state of the free planar rotor is unique (non-degenerated). All the excited states are two-fold degenerated, i.e. level degeneracy = 2.

Density of state: number of states per energy interval (usually defined in the thermodynamic limit to smooth out the discreteness).

D(E)=((dN)/(dE))∝(1/(Sqrt[E])).

If the rotor is electrically charged, it can be driven by electromagnetic field. It can absorb an incident photon of frequency ω and transits from the ground state (Ket[0]) to an excited state (Ket[N]), if ℏ ω=(Subscript[E, N])-(Subscript[E, 0]). The absorption rate (at low temperature) will be proportional to D((Subscript[E, 0])+ℏ ω).

Reflection Symmetry

The symmetry can be implemented by the unitary operator (OverHat[P])

It is a (Subscript[ℤ, 2]) symmetry, i.e. ((OverHat[P])^2)=𝟙, so ((OverHat[P])^(-1))=(SuperDagger[(OverHat[P])])=(OverHat[P]).

The Hamiltonian (OverHat[H]) is invariant under the symmetry transformation (OverHat[P])

(OverHat[P])(OverHat[H])(OverHat[P])=(OverHat[H]),

because (OverHat[H]) and (OverHat[P]) commute.

(Subscript[E, N])(Ket[N])=(OverHat[H])(Ket[N])=(OverHat[P])(OverHat[H])(OverHat[P])(Ket[N])=(OverHat[P])(OverHat[H])(Ket[-N])=(Subscript[E, -N])(OverHat[P])(Ket[-N])=(Subscript[E, -N])(Ket[N]),

(OverHat[R])(α)(OverHat[R])(β)=(OverHat[R])(α+β),
((OverHat[P])^2)=𝟙,
(OverHat[R])(α)(OverHat[P])=(OverHat[P])(OverHat[R])(-α).

The only one-dimensional irreducible representation is the trivial representation (Ket[0]).

The rest of the irreducible representations are two-dimensional, as spanned by (Ket[±N]) for N=1,2,….

Raising and Lowering Operators

(OverHat[θ])=∫dθ(Ket[θ])θ(Bra[θ]).

(OverHat[R])(2π)(OverHat[θ])(SuperDagger[(OverHat[R])])(2π)=(OverHat[θ])+2π 𝟙≠(OverHat[θ]).

(e^(+i (OverHat[θ]))): raising operator, (e^(-i (OverHat[θ]))) lowering operator.

Or to be Hermitian, what we really measure should be the real and imaginary parts of (e^(±i (OverHat[θ])))

cos (OverHat[θ])=∫dθ(Ket[θ])cos θ(Bra[θ]),
sin (OverHat[θ])=∫dθ(Ket[θ])sin θ(Bra[θ]).

(e^(±i (OverHat[θ])))(Ket[N])=(e^(±i (OverHat[θ])))(1/(Sqrt[2π]))∫dθ (e^(i N θ))(Ket[θ])
=(1/(Sqrt[2π]))∫dθ (e^(i N θ))(e^(±i (OverHat[θ])))(Ket[θ])
=(1/(Sqrt[2π]))∫dθ (e^(i N θ))(e^(±i θ))(Ket[θ])
=(1/(Sqrt[2π]))∫dθ (e^(i (N±1) θ))(Ket[θ])
=(Ket[N±1]).

(OverHat[θ]) generates the shift of angular momentum (e^(±i (OverHat[θ])))=(∑_N)(Ket[N±1])(Bra[N]).

(OverHat[N]) generates the rotation (e^(i (OverHat[N])α))=∫dθ(Ket[θ-α])(Bra[θ]).

Charged Rotor in Electric Field

V(θ)=g (1-cos θ),

DynamicModule[{t=π/2,dt=0.12,dyn=False},
Dynamic[If[dyn,t=t+dt];
EventHandler[Deploy[Graphics[{Circle[{0,0},1],AbsolutePointSize[6],Point[ReIm@Exp[0.2π I Sin[t]]],{AbsoluteThickness[0.8],{Dashed,Line[ReIm/@{0,Exp[0.2π I Sin[t]]}]}},
{Arrowheads[0.1],AbsoluteThickness[1],Table[Arrow[{{-1.5,y},{1.5,y}}],{y,-1.2,1.2,0.6}],Text["\!\( E\)",{1.2,0.85}]}},PlotRange->1.5,ImageSize->100]],{"MouseClicked":>(dyn=Not[dyn])}]]]

(OverHat[H])=(1/2)((OverHat[N])^2)+g 𝟙-(g/2) ((e^(+i (OverHat[θ])))+(e^(-i (OverHat[θ]))))
=(∑_N)((((N^2)/2)+g)(Ket[N])(Bra[N])-(g/2)(Ket[N+1])(Bra[N])-(g/2)(Ket[N-1])(Bra[N])).

(OverHat[H])≏(({{⋱, ⋱,  ,  ,  ,  ,  }, {⋱, 2+g, -g/2,  ,  ,  ,  }, { , -g/2, 1/2+g, -g/2,  ,  ,  }, { ,  , -g/2, g, -g/2,  ,  }, { ,  ,  , -g/2, 1/2+g, -g/2,  }, { ,  ,  ,  , -g/2, 2+g, ⋱}, { ,  ,  ,  ,  , ⋱, ⋱}})).

(OverHat[H])(Ket[n])=(Subscript[E, n])(Ket[n]).

In numerics, we need to truncate the angular momentum basis to N∈[-M,M], altogether 2M+1 basis states. If we only care about the low-energy physics, large angular momentum states are not important.

M=32;

We will consider a relatively large g, such that the rotor is almost pinned around θ=0 to do small oscillations => approximated by a harmonic oscillator.

g=256;

(OverHat[H])(Overscript[→, θ->0])(1/2)((OverHat[N])^2)+(g/2) ((OverHat[θ])^2)+….

Construct and diagonalize the Hamiltonian (a (2M+1)×(2M+1) matrix)

H=SparseArray[{Band[{1,1}]->Range[-M,M]^2/2+g,Band[{1,2}]->-g/2,Band[{2,1}]->-g/2},{2M+1,2M+1}];
eigs=SortBy[First]@Thread@Eigensystem@N@H;

Now eigs contains the full list of ((Subscript[E, n]),(Ket[n])) pairs (that solves the eigen equation Eq. ()), with (Ket[n]) represented by a state vector (Subscript[(OverTilde[ψ]), n]) in the angular momentum basis (each with \[RawEscape]2M+1 components)

(Ket[n])=(∑_N)(Subscript[(OverTilde[ψ]), n,N])(Ket[N]).

The low-lying energy levels (n≪M) follow a linear relation with the level index n => the neighboring level spacings are equal (denoted as ℏ ω)

(Subscript[E, n])≃ℏ ω (n+(1/2)).

ListPlot[eigs[[;;10,1]],GridLines->{Range[0,2M+1],Range[0,2M+1]eigs[[1,1]]},PlotStyle->Black,PlotMarkers->Graphics[{EdgeForm[Black],White,Disk[{0,0},Offset[{2,2}]]}],Prolog->{AbsoluteThickness[1],Dashed,Line[{#,eigs[[1,1]](2(#-1)+1)}&/@{0,2M}]},
FrameLabel->{"\!\( n\)","\!\(E\_n\)"},AspectRatio->1,ImageSize->200]

In fact ω is related to g by ω=(g^(1/2)) (to be discussed later).

The density of state is uniform (E independent) at low-energy

D(E)=((dn)/(dE))≃(1/(ℏ ω))=const.

Applying the electric field changes the low-energy density of state drastically. This is a measurable effect in the absorption spectrum D((Subscript[E, 0])+ℏ ω).

What does the wave function of each eigenstate look like in the rotor basis?

(Ket[n])=(∑_N)(Subscript[(OverTilde[ψ]), n,N])(Ket[N])
=(1/(Sqrt[2π]))∫dθ (∑_N)(Subscript[(OverTilde[ψ]), n,N])(e^(i N θ))(Ket[θ])
=∫dθ (Subscript[ψ, n])(θ)(Ket[θ]),

where (Subscript[ψ, n])(θ) is given by

(Subscript[ψ, n])(θ)=(1/(Sqrt[2π]))(∑_N)(Subscript[(OverTilde[ψ]), n,N])(e^(i N θ)).

Some examples of the wave function (Subscript[ψ, n])(θ) (blue - Re (Subscript[ψ, n])(θ), red - Im (Subscript[ψ, n])(θ)):

Row[Plot[Evaluate[ReIm[#3.Exp[I Range[-M,M]θ]]],{θ,-π,π},PlotRange->{-4.5,4.5},PlotLabel->Style["\!\(n="<>ToString[#1]<>"\)\n\!\(E\_"<>ToString[#1]<>"="<>ToString[NumberForm[#2/(2eigs[[1,1]]),3]]<>"ℏω\)",14],Frame->None,Ticks->{{-π,0,π},None},AxesLabel->{"θ",None},ImageSize->120]&@@@MapThread[Prepend,{#,Range[0,Length@#-1]}]&@eigs[[;;6]]]

Potential Momentum

(OverHat[H])=(((OverHat[p])^2)/(2m))+V((OverHat[x])).

Potential energy: as the particle moves from one position (Subscript[x, 1]) to another (Subscript[x, 2]), if V((Subscript[x, 1]))≠V((Subscript[x, 2])), the difference V((Subscript[x, 2]))-V((Subscript[x, 1])) will be released in the form of energy (and can be converted to the kinetic energy).

For a particle with charge q in an electrostatic potential φ(x), we have V(x)=q φ(x).

Potential momentum: as the particle travels from one time (Subscript[t, 1]) to another (Subscript[t, 2]), if q A((Subscript[t, 1]))≠q A((Subscript[t, 2])), the difference q A((Subscript[t, 2]))-q A((Subscript[t, 1])) will be released in the form of momentum (and can be converted to the kinetic momentum).

(∫_Σ)((∂B)/(∂t))·dS=-(∮_(∂Σ))E·dl,

DynamicModule[{t=0,dt=0.05,v=0,a=0.1,state=0},
Dynamic[
Switch[state,
1,t=t+v dt;a=0.08;If[v<1,v=v+a dt,v=1];,
2,t=t+v dt;a=-0.08;If[v>0,v=v+a dt,v=0];,
0,Null];
EventHandler[Deploy[Graphics[{Circle[{0,0},1],AbsolutePointSize[6],Point[ReIm@Exp[-2π I t]],{AbsoluteThickness[0.8],{Dashed,Line[ReIm/@{0,Exp[-2π I t]}]}},
If[0<v<1,{Red,Arrowheads[0.1],AbsoluteThickness[1],Arrow[ReIm[# Exp[-Sign[a]I 2 π Range[0,64]/64]]&/@{0.7,1.2}],Text["\!\( E\)",{1.2,0.8}]},{}],
{Blue,Opacity[v],{Translate[{AbsoluteThickness[1],Circle[{0,0},0.1],AbsolutePointSize[3],Point[{0,0}]},#]&/@Cases[0.5Tuples[Range[-5,5],2].{{1/2,Sqrt[3]/2},{1/2,-Sqrt[3]/2}},p_/;Norm[p]<1],Text["\!\( B\)",{-0.28,-0.2}]}}},PlotRange->1.5,ImageSize->100]],{"MouseClicked":>(state=Mod[state+1,3])}]]]

(∫_Σ)B·dS=(∮_(∂Σ))A·dl (Overscript[⟹, on the ring])A=((B R)/2).

Graphics[{Circle[{0,0},1],AbsolutePointSize[6],
{AbsoluteThickness[0.8],Dashed,Line[ReIm/@{0,1}],Text["\!\( R\)",{0.45,0},{0,-0.7}]},
{Green,Arrowheads[0.1],AbsoluteThickness[1],Arrow[ReIm[# Exp[I 2 π Range[0,64]/64]]&/@{0.7,1.2}],Text["\!\( A\)",{1.2,0.8}]},
{Blue,{Translate[{AbsoluteThickness[1],Circle[{0,0},0.1],AbsolutePointSize[3],Point[{0,0}]},#]&/@Cases[0.5Tuples[Range[-5,5],2].{{1/2,Sqrt[3]/2},{1/2,-Sqrt[3]/2}},p_/;Norm[p]<1],Text["\!\( B\)",{-0.28,-0.2}]}}},PlotRange->1.5,ImageSize->100]

m v - kinetic momentum,

q A - potential momentum,

total momentum (kinetic + potential)

p=m v+q A,

which is conserved.

({{{, ({{i ℏ(∂_t)=H=(1/2)m (v^2)+q φ,}, {-i ℏ(∂_x)=p=m v+q A,}})}})=>H=(1/(2m))(((p-q A))^2)+q φ.

i ℏ(∂_t)ψ=(OverHat[H]) ψ=[(1/(2m))(((-i ℏ (∂_x)-q A))^2)+q φ]ψ.

(i(∂_t)-φ)ψ=(1/(2m))(((-i (∂_x)-A))^2)ψ.

Wave function ψ(x,t) is not physical, only the probability distribution p(x,t)=((|ψ(x,t)|)^2) is physical.

Attaching an arbitrary phase χ(x,t) to the wave function at each space time point

ψ(x,t)→(e^(i χ(x,t)))ψ(x,t)

does not affect p(x,t) => Eq. () is a gauge transformation (= do-nothing/renaming)

However, gauge transformation does affect how (∂_t) and (∂_x) act on the wave function!

i (∂_t)ψ->i(∂_t)((e^(i χ))ψ)=(e^(i χ))(i(∂_t)-(∂_t)χ)ψ,
-i (∂_x)ψ->-i (∂_x)((e^(i χ))ψ)=(e^(i χ))(-i(∂_x)+(∂_x)χ)ψ.

φ and A must transform accordingly to keep the Schrödinger equation Eq. () invariant

ψ→(e^(i χ))ψ, (Subscript[A, μ])->(Subscript[A, μ])+(∂_μ)χ.

Charged Rotor in Magnetic Field

(OverHat[H])=((ℏ^2)/(2I))((((OverHat[N])-(Subscript[N, Φ])))^2),

Graphics[{Circle[{0,0},1],AbsolutePointSize[6],
{AbsoluteThickness[0.8],Dashed,Line[ReIm/@{0,1}],Text["\!\( R\)",{0.45,0},{0,-0.7}]},
{Green,Arrowheads[0.1],AbsoluteThickness[1],Arrow[ReIm[# Exp[I 2 π Range[0,64]/64]]&/@{0.7,1.2}],Text["\!\( A\)",{1.2,0.8}]},
{Blue,{Translate[{AbsoluteThickness[1],Circle[{0,0},0.1],AbsolutePointSize[3],Point[{0,0}]},#]&/@Cases[0.5Tuples[Range[-5,5],2].{{1/2,Sqrt[3]/2},{1/2,-Sqrt[3]/2}},p_/;Norm[p]<1],Text["\!\( B\)",{-0.28,-0.2}]}}},PlotRange->1.5,ImageSize->100]

Magnetic flux Φ=(∫_Σ)B·dS=(∮_(∂Σ))A·dl,

Φ=π (R^2)B=2π R A.

Linear potential momentum q A

q A=((q Φ)/(2π R)).

Angular potential momentum (Subscript[L, Φ])=R×(q A)

(Subscript[L, Φ])=R (q A)=((q Φ)/(2π)).

in unit of ℏ (recall that L=ℏ N)

(Subscript[N, Φ])=((Subscript[L, Φ])/ℏ)=((q Φ)/(2π ℏ))=(Φ/((h/q)))=(Φ/(Subscript[Φ, 0])).

Block[{},
Show[Plot[(Ν-1/2)^2/2,{Ν,-2,3},PlotStyle->Black],
ListPlot[Table[{Ν,(Ν-1/2)^2/2},{Ν,-2,3}],PlotStyle->Black,PlotMarkers->Graphics[{EdgeForm[Black],White,Disk[{0,0},Offset[{2,2}]]}]],
GridLines->{Range[-2,3],(Range[3]-1/2)^2/2},
FrameLabel->{"\!\( N\)","\!\(E\_N\)"},ImageSize->200]]

Quantum Anomaly*

(OverHat[H])=(1/2)((((OverHat[N])-𝟙/2))^2).

(OverHat[P])'=(∑_N)(Ket[1-N])(Bra[N])=(e^(+i (OverHat[θ])))(∑_N)(Ket[-N])(Bra[N])=(e^(+i (OverHat[θ])))(OverHat[P]),

(OverHat[P])=(∑_N)(Ket[-N])(Bra[N]) was the conventional reflection operator in Eq. ().

The anomalous reflection (OverHat[P])' is the conventional reflection (OverHat[P]) followed by the rasing operator (e^(+i (OverHat[θ]))), which can be considered as a gauge transformation by redefining each rotor basis state by a different phase factor

(Ket[θ])→(e^(i (OverHat[θ])))(Ket[θ])=(e^(i θ))(Ket[θ]).

(OverHat[R])(α)(OverHat[R])(β)=(OverHat[R])(α+β),
((OverHat[P])^(′2))=𝟙,
(OverHat[R])(α)(OverHat[P])'=(e^(i α))(OverHat[P])'(OverHat[R])(-α).

(OverHat[H])=(1/2)((((OverHat[N])-(Subscript[N, Φ])𝟙))^2)-(Subscript[g, 2]) cos 2 (OverHat[θ])-(Subscript[g, 4]) cos 4 (OverHat[θ])-(Subscript[g, 6]) cos 6 (OverHat[θ])-…

Classical level: the system respects two symmetries

Two-fold rotation R(π): θ→θ+π,

Reflection P: θ→-θ.

Quantum level: the symmetry group depends on (Subscript[N, Φ])

({{(Subscript[N, Φ])=0, (Subscript[N, Φ])=1/2}, {(((OverHat[R])(π))^2)=𝟙,
((OverHat[P])^2)=𝟙,
(OverHat[R])(π)(OverHat[P])=(OverHat[P])(OverHat[R])(π), (((OverHat[R])(π))^2)=𝟙,
((OverHat[P])^(′2))=𝟙,
(OverHat[R])(π)(OverHat[P])'=-(OverHat[P])'(OverHat[R])(π)}, {(Subscript[ℤ, 2])×(Subscript[ℤ, 2]), (Subscript[ℤ, 2])⋊(Subscript[ℤ, 2])}})

(Subscript[ℤ, 2])×(Subscript[ℤ, 2]) is Abelian and admits one-dimensional representations => allows non-degenerated levels to appear in the spectrum

(Subscript[ℤ, 2])⋊(Subscript[ℤ, 2]) does not admit one-dimensional representations (its representation is two-dimensional) => all energy levels are two-fold degenerated

Block[{g=10},Plot[-g Cos[2θ]-g Cos[4θ]-g Cos[6θ],{θ,0,2π},PlotStyle->Black,Axes->False,FrameTicks->{Automatic,{{0,{π/2,"π/2"},π,{3π/2,"3π/2"},2π},Automatic}},FrameLabel->{"θ","\!\(V(θ)\)"},AspectRatio->0.4,ImageSize->240]]

Row@Table[Block[{M=32,g=10,H,Es},
H=SparseArray[{Band[{1,1}]->(Range[-M,M]-NΦ)^2/2,Band[{1,3}]->-g/2,Band[{3,1}]->-g/2,Band[{1,5}]->-g/2,Band[{5,1}]->-g/2,Band[{1,7}]->-g/2,Band[{7,1}]->-g/2},{2M+1,2M+1}];
Es=Sort@Eigenvalues[N@H];
ListPlot[Es[[;;16]],PlotRange->{{0.5,16.5},{-22,35}},
GridLines->{Range[0,2M+1],Es},PlotStyle->Black,PlotMarkers->Graphics[{EdgeForm[Black],White,Disk[{0,0},Offset[{2,2}]]}],PlotLabel->StringTemplate["\!\(N\_Φ=`1`\)"][NΦ],FrameLabel->{"\!\( n\)",If[NΦ==0,"\!\(E\_n\)",None]},Axes->False,FrameTicks->{If[NΦ==0,{Automatic,Automatic},{None,Automatic}],{Automatic,Automatic}},AspectRatio->2,ImageSize->{Automatic,260}]],{NΦ,{0,1/2}}]

H=(1/2)(((Subscript[E, C])((OverHat[N])-(Subscript[N, e])𝟙))^2)-(Subscript[E, J])cos 2 (OverHat[θ]),

(OverHat[N]): the number of electrons in the capacitor,

cos 2 (OverHat[θ]): the operator describing Cooper pair tunneling through a Josephson junction.